ut_testDriverMod.F90

Go to the documentation of this file.

!! NOTICE
!!  Copyright 2022 UChicago Argonne, LLC and contributors
!!
!!  Licensed under the Apache License, Version 2.0 (the "License");
!!  you may not use this file except in compliance with the License.
!!
!!  Unless required by applicable law or agreed to in writing, software
!!  distributed under the License is distributed on an "AS IS" BASIS,
!!  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
!!  See the License for the specific language governing permissions and
!!  limitations under the License.
!!
 
#include "constants.h"
 
module ut_testDriverMod
    implicit none
    private
 
    integer, save :: my_n_tests = 0
    integer, save :: my_n_failed = 0
    real,    save :: my_t_start = 0.0d0
    logical, save :: is_testing = .FALSE.
 
    interface assertEqual
        procedure :: assertEqualInt
        procedure :: assertEqualReal
    end interface assertEqual
 
    interface assertSetEqual
        procedure :: assertSetEqual2dIntArray
    end interface assertSetEqual
 
    public :: start_test_run
    public :: finish_test_run
 
    public :: assertTrue
    public :: assertFalse
    public :: assertEqual
    public :: assertSetEqual
    public :: assertAlmostEqual
 
contains
 
    subroutine start_test_run()
        use Driver_Interface, ONLY : Driver_abort
 
        if (is_testing) then
            call Driver_abort("[start_test_run] Already testing")
        end if
 
        is_testing = .TRUE.
 
        my_t_start = 0.0d0
        call cpu_time(my_t_start)
    end subroutine start_test_run
 
    subroutine finish_test_run
        use Driver_data,      ONLY : dr_globalMe
        use Driver_Interface, ONLY : Driver_abort
 
        real :: my_t_end
        real :: my_walltime
 
        integer :: file_unit
        integer :: ut_getFreeFileUnit
 
        character(4)                 :: rank_str 
        character(MAX_STRING_LENGTH) :: fileName
 
        if (.NOT. is_testing) then
            call Driver_abort("[finish_test_run] Not testing yet")
        end if
 
        is_testing = .FALSE.
 
        call cpu_time(my_t_end)
        my_walltime = my_t_end - my_t_start
 
        ! DEV: TODO reduction to collect number of tests/fails/max walltime?
        if (dr_globalMe == MASTER_PE) then
            ! Print result to standard out
            write(*,*)
            if (my_n_failed == 0) then
                write(*,*) "SUCCESS - ", &
                           (my_n_tests - my_n_failed), "/", my_n_tests, ' passed' 
            else 
                write(*,*) "FAILURE - ", &
                           (my_n_tests - my_n_failed), "/", my_n_tests, ' passed'
            end if
            write(*,*)
            write(*,*) 'Walltime = ', my_walltime, ' s'
            write(*,*)
 
            ! Create log file for automatic testing on server
            write(rank_str,"(I4.4)") dr_globalMe
            filename = "unitTest_" // rank_str
            file_unit = ut_getFreeFileUnit()
            OPEN(file_unit, file=filename)
            if (my_n_failed == 0) then
                write(file_unit,'(A)') 'SUCCESS all results conformed with expected values.' 
            else
                write(file_unit,'(A)') 'FAILURE'
            end if
            CLOSE(file_unit)
        end if
    end subroutine finish_test_run
 
    subroutine assertTrue(a, msg)
        logical,      intent(IN) :: a
        character(*), intent(IN) :: msg
 
        character(256) :: buffer = ""
        
        if (.NOT. a) then
            write(buffer,'(A)') msg
            write(*,*) TRIM(ADJUSTL(buffer))
            my_n_failed = my_n_failed + 1
        end if
        my_n_tests = my_n_tests + 1
    end subroutine assertTrue
 
    subroutine assertFalse(a, msg)
        logical,      intent(IN) :: a
        character(*), intent(IN) :: msg
 
        character(256) :: buffer = ""
        
        if (a) then
            write(buffer,'(A)') msg
            write(*,*) TRIM(ADJUSTL(buffer))
            my_n_failed = my_n_failed + 1
        end if
        my_n_tests = my_n_tests + 1
    end subroutine assertFalse
 
    subroutine assertEqualInt(a, b, msg)
        integer,      intent(IN) :: a
        integer,      intent(IN) :: b
        character(*), intent(IN) :: msg
 
        character(256) :: buffer = ""
 
        if (a /= b) then
            write(buffer,'(A,I5,A,I5)') msg, a, " != ", b
            write(*,*) TRIM(ADJUSTL(buffer))
            my_n_failed = my_n_failed + 1
        end if
        my_n_tests = my_n_tests + 1
    end subroutine assertEqualInt
 
    subroutine assertEqualReal(a, b, msg)
        real,         intent(IN) :: a
        real,         intent(IN) :: b
        character(*), intent(IN) :: msg
 
        character(256) :: buffer = ""
 
        if (a /= b) then
            write(buffer,'(A,F15.8,A,F15.8)') msg, a, " != ", b
            write(*,*) TRIM(ADJUSTL(buffer))
            my_n_failed = my_n_failed + 1
        end if
        my_n_tests = my_n_tests + 1
    end subroutine assertEqualReal
 
    subroutine assertAlmostEqual(a, b, prec, msg)
        real,         intent(IN) :: a
        real,         intent(IN) :: b
        real,         intent(IN) :: prec
        character(*), intent(IN) :: msg
 
        character(256) :: buffer = ""
 
        if (ABS(b - a) > prec) then
            write(buffer,'(A,F15.8,A,F15.8)') msg, a, " != ", b
            write(*,*) TRIM(ADJUSTL(buffer))
            my_n_failed = my_n_failed + 1
        end if
        my_n_tests = my_n_tests + 1
    end subroutine assertAlmostEqual
 
    subroutine assertSetEqual2dIntArray(A, B, msg)
        integer,      intent(IN) :: A(:, :)
        integer,      intent(IN) :: B(:, :)
        character(*), intent(IN) :: msg
 
        logical        :: in_set
        logical        :: failed
        integer        :: j, k
 
        my_n_tests = my_n_tests + 1
 
        ! Confirm A subset of B
        failed = .FALSE.
        do j = 1, SIZE(A, 1)
            in_set = .FALSE.
            do k = 1, SIZE(B, 1)
                if (ALL(A(j, :) == B(k, :))) then
                    in_set = .TRUE.
                    exit
                end if
            end do
 
            if (.NOT. in_set) then
                write(*,*) msg, " - ", A(j, :), " of A not in B"
                failed = .TRUE.
            end if
        end do
 
        ! Confirm B subset of A
        do j = 1, SIZE(B, 1)
            in_set = .FALSE.
            do k = 1, SIZE(A, 1)
                if (ALL(B(j, :) == A(k, :))) then
                    in_set = .TRUE.
                    exit
                end if
            end do
 
            if (.NOT. in_set) then
                write(*,*) msg, " - ", B(j, :), " of B not in A"
                failed = .TRUE.
            end if
        end do
 
        if (failed) then
            my_n_failed = my_n_failed + 1
        end if
    end subroutine assertSetEqual2dIntArray
 
end module ut_testDriverMod