ut_convertToArrayIndicies.F90

Go to the documentation of this file.

!! NOTICE
!!  Copyright 2022 UChicago Argonne, LLC and contributors
!!
!!  Licensed under the Apache License, Version 2.0 (the "License");
!!  you may not use this file except in compliance with the License.
!!
!!  Unless required by applicable law or agreed to in writing, software
!!  distributed under the License is distributed on an "AS IS" BASIS,
!!  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
!!  See the License for the specific language governing permissions and
!!  limitations under the License.
!!
!*******************************************************************************
 
subroutine ut_convertToArrayIndicies(dims, memoryOffset, arrayLBound, arrayUBound, elementCoord)
 
  implicit none
  integer, intent(IN) :: dims, memoryOffset
  integer, dimension(1:dims), intent(IN) :: arrayLBound, arrayUBound
  integer, dimension(1:dims), intent(OUT) :: elementCoord
 
  integer, dimension(1:dims) :: elementCount, elementsToNextIndicy
  integer :: i, j, memoryOffsetRemainder
 
  !This is a count of the number of memory elements between successive array elements.
  elementsToNextIndicy(1) = 1
  do i = 2, dims, 1
     elementsToNextIndicy(i) = elementsToNextIndicy(i-1) * (arrayUbound(i-1) - arrayLbound(i-1) + 1)
  end do
 
  memoryOffsetRemainder = memoryOffset
  do j = dims, 2, -1
     elementCount(j) = (memoryOffsetRemainder / elementsToNextIndicy(j))
     memoryOffsetRemainder = memoryOffsetRemainder - (elementCount(j) * elementsToNextIndicy(j))
  end do
  elementCount(1) = memoryOffsetRemainder
 
 
#ifdef DEBUG_MODE
  do i = 1, dims, 1
     if (elementCount(i) > (arrayUbound(i) - arrayLbound(i) + 1)) then
        print *, "[ConvertToArrayIndicies]: Invalid data passed!"
        return
     end if
  end do
#endif
 
  !Add the array lower bound so that the caller can pass a non-unit based array.
  elementCoord(1:dims) = elementCount(1:dims) + arrayLBound(1:dims)
  
end subroutine ut_convertToArrayIndicies