ut_printMatrix.F90

Go to the documentation of this file.

!! NOTICE
!!  Copyright 2022 UChicago Argonne, LLC and contributors
!!
!!  Licensed under the Apache License, Version 2.0 (the "License");
!!  you may not use this file except in compliance with the License.
!!
!!  Unless required by applicable law or agreed to in writing, software
!!  distributed under the License is distributed on an "AS IS" BASIS,
!!  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
!!  See the License for the specific language governing permissions and
!!  limitations under the License.
!!
 
subroutine ut_printMatrix (fileUnit,                   &
                           title,                      &
                           rowMinMatrix, rowMaxMatrix, &
                           colMinMatrix, colMaxMatrix, &
                           rowMinPrint , rowMaxPrint,  &
                           colMinPrint , colMaxPrint,  &
                           matrix                      )
 
  use Driver_interface,  ONLY : Driver_abort
 
  implicit none
 
  integer,           intent (in) :: fileUnit
  character (len=*), intent (in) :: title
  integer,           intent (in) :: rowMinMatrix, rowMaxMatrix
  integer,           intent (in) :: colMinMatrix, colMaxMatrix
  integer,           intent (in) :: rowMinPrint , rowMaxPrint
  integer,           intent (in) :: colMinPrint , colMaxPrint
  real,              intent (in) :: matrix (rowMinMatrix : rowMaxMatrix , colMinMatrix : colMaxMatrix)
 
  integer :: block
  integer :: col, colBeg, colEnd
  integer :: nColBlocks, nColTotal
  integer :: row
 
  integer, parameter :: nColPerBlock = 10
!
!
!     ...Print out the title.
!
!
  write (fileUnit,'(/)')
  write (fileUnit,'(a)') title
  write (fileUnit,'(/)')
!
!
!     ...Check, if printing index ranges are ok.
!
!
  if (rowMaxPrint > rowMaxMatrix .or. rowMinPrint < rowMinMatrix) then
      call Driver_abort("ut_printMatrix: Matrix row printing range out of bounds")
  end if
 
  if (colMaxPrint > colMaxMatrix .or. colMinPrint < colMinMatrix) then
      call Driver_abort("ut_printMatrix: Matrix column printing range out of bounds")
  end if
 
  if (rowMinPrint > rowMaxPrint .or. colMinPrint > colMaxPrint) then
      call Driver_abort("ut_printMatrix: No matrix printing range!")
  end if
!
!
!     ...Everything ok. Start the printing.
!
!
  nColTotal  = colMaxPrint - colMinPrint + 1
  nColBlocks = nColTotal / nColPerBlock
!
!
!     ...Print all full column blocks.
!
!
  colEnd = colMinPrint - 1
 
  do block = 1,nColBlocks
 
     colBeg = colEnd + 1
     colEnd = colEnd + nColPerBlock
 
     write (fileUnit,'(/,1x,10i14)') (col , col = colBeg , colEnd)
     write (fileUnit,'(/)')
 
     do row = rowMinPrint ,rowMaxPrint
        write (fileUnit,'(i6,10es14.6)') row, (matrix(row,col), col = colBeg , colEnd)
     end do
 
  end do
!
!
!     ...Print remaining partial column block (if any).
!
!
  colBeg = colEnd + 1
  
  if (colBeg > colMaxPrint) return
 
  write (fileUnit,'(/,1x,10i14)') (col , col = colBeg , colMaxPrint)
  write (fileUnit,'(/)')
 
  do row = rowMinPrint ,rowMaxPrint
     write (fileUnit,'(i6,10es14.6)') row, (matrix(row,col), col = colBeg , colMaxPrint)
  end do
!
!
!     ...Ready!
!
!
  return
end subroutine ut_printMatrix